Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00122_button routines.ls

Text File | 2004-07-11 | 3.4 KB | 121 lines

-- BUTTON

-- This routine will "bounce" a sprite on stage.
-- This bounce occurs because of a swapping of 1 cast member with another.
--
-- mouseDown over button = down state
-- mouseDown outside button = up state
-- mouse released over button returns TRUE
-- mouse released outside of button returns FALSE
--
-- NOTE:
-- When this handler is done, it unpuppets the sprite, there is no check for a previously
-- puppeted sprite state.
--
-- naming convention...
-- normal button = the name of cast member in whatSprite
-- down button = same as above + ",down"
--
-- other states could be...    + ",gray"
--                             + ",next"
--                             + ",hot"
-- you get the idea...
--
on bounceButton whatSprite
  -- do something to figure out if we are in an irregularly shaped button.
  -- set thisCast = the mouseCast

  -- do all the seeking up front
  set normalName = item 1 of the name of the member of sprite whatSprite
  set normalCast = the number of member normalName
  set downName = normalName & ",down"
  set downCast = the number of member downName

  -- debugging setup
  if the controlDown then
    put "normal name: " & normalName
    put "cast member: " & normalCast
    put ""
    put "down name: " & downName
    put "cast number: " & downCast
  end if
  -- end debug

  -- puppet the sprite
  puppetSprite whatSprite, TRUE

  -- assume an immediate hit
  set the castNum of sprite whatSprite = downCast

  updateStage

  wait (20)

  -- while the mouse is down, constantly check the button
  repeat while the stillDown
    if inside(point(the mouseH, the mouseV), the rect of sprite whatSprite) then
      -- we are still over the button
      -- using "inside" disallows the whole matte ink thing
      -- is that a-ok?

      -- make sure it is down
      set the castNum of sprite whatSprite = downCast

    else
      -- we have left the button

      -- pop it back up
      set the castNum of sprite whatSprite = normalCast
    end if

    -- draw it in the proper state
    updateStage
  end repeat

  -- check to see if we are still inside the button
  if inside(point(the mouseH, the mouseV), the rect of sprite whatSprite) then
    -- we are still over the button
    -- return it to normal and return true
    set the castNum of sprite whatSprite = normalCast
    puppetSprite whatSprite, FALSE
    updateStage

    -- return the positive reaction
    return TRUE

  else
    -- we are outside the button
    -- return it to normal and return FALSE
    set the castNum of sprite whatSprite = normalCast
    puppetSprite whatSprite, FALSE
    updateStage

    return FALSE
  end if

  -- just in case
  return FALSE
end

--------------------------------------------------------------------------
-- this will blink a button to the hilited state in an exit frame
-- very similar to a toggle button

on blinkButton whatSprite
  puppetSprite whatSprite, TRUE

  set currentName = the name of member (the member of sprite whatSprite)
  set rootName = item 1 of currentName

  -- now we want to see what state it is in currently, and flip it
  -- from normal to hilited (the hilite always implies at least a working button).
  if item 2 of currentName = "hot" then
    -- we are hot already, make it normal
    set the member of sprite whatSprite = the number of member rootName
  else
    set the member of sprite whatSprite = the number of member (rootName & ",hot")
  end if

  updateStage
end